A Nonlinear System - Phase Plane Methods

Here is an example of a nonlinear, autonomous, homogeneous 2X2 systems of ordinary differential equations.

This notebook was created by T. Shelton, Southwestern University to supplement a handout for  Differential Equations II, updated for Mathematica 7.0.

reference  Differential Equations: Theory, Technique, and Practice, Simmons & Krantz, McGraw-Hill Co, Inc. 2007

dx/dt=f[x,y]
dy/dt=g[x,y]

Clear[f,g]
f[x_,y_]:= y
g[x_,y_]:=-2x-y+x^3+x^2

nullclines

Solve[f[x,y]==0]

Solve[g[x,y]==0]

equilibria

Solve[{f[x,y]==0,g[x,y]==0}]

graphing window containing interesting places

Clear[xmin,xmax,ymin,ymax]
xmin=-3.0;
xmax=3.0;
ymin=-5.0;
ymax=5.0;

plots of nullclines and equilibria

Clear[np1,np2,np]
np1 =Plot[0,{x, xmin, xmax},PlotStyle->{Red,Dashed,Thick}];
np2 = Plot[x^3+x^2-2x,{x, xmin, xmax},PlotStyle->{Blue,Dashed,Thick}];
np = Show[{np1,np2},PlotRange->{{xmin,xmax},{ymin,ymax}}];
Clear[pts]
pts = Graphics[{PointSize[Large],Point[{{-2,0}, {0,0},{1,0}}]}];
Show[np,pts]

the direction field

Clear[vPlot]
vPlot = VectorPlot[{f[x,y],g[x,y]},{x,xmin,xmax},{y,ymin,ymax}];

all together

Show[np,pts,vPlot]

the region between the x-nullcline and the y-nullcline for 0 < x < 1 has no arrows.  Focus on this region.

Show[{Plot[x^3+x^2-2x,{x, -.5,1.5},PlotStyle->{Blue,Dashed,Thick}],
VectorPlot[{f[x,y],g[x,y]},{x,-.5, 1.5},{y,-1,.5}]},
PlotRange->{-1,.5}]

Show[{np,pts,
VectorPlot[{f[x,y],g[x,y]},{x,-3,2},{y,-3,3}]},
PlotRange->{{-3,2},{-3,3}}]