Motivations for speed and more

Dr. Therese Shelton
Southwestern University

Example which motivates the derivative of a vector-valued function.

It is expected that the reader has already seen the parm1 and parm2 files.

Basics

Clearing out the variables used avoids problems.

Clear[x,y,tmin,tmax, xmin,xmax,ymin,ymax,plotAll]

Define the functions for the parametric plot.

x[t_]:=(((t^3) - t)/((t^4) + 1));
 y[t_]:=(( t)/((t^4) + 1));

Define the graphing window. Making these decimals is a good idea.

tmin=-10.0;    tmax=10.0;
xmin = -0.5;    xmax=0.5;
ymin=-0.6; ymax=0.6;

A static image

plotAll=ParametricPlot[{x[t],y[t]},{t,tmin,tmax},PlotRange->{{xmin,xmax},{ymin,ymax}},AspectRatio->Automatic]

Clear[colorr,colorx,colory, colr,colx,coly]

colorr=RGBColor[0,0,0];
colorx=RGBColor[1.,0.,0.]; 
colory=RGBColor[0.,0.,1.];

colx="red";
coly="blue";
colr = "black";

StringJoin[" r is ",colr,";  x is ",colx, ";   y is ",coly]

(see "parm3.nb" for projections)

Cool phenomenon that motivates velocity

Suggestion:  begin with a small number of intervals, like numberIntervals = 15  .

You should be able to use the table to indicate a direction on the graph.

Clear[numberIntervals, deltat];

numberIntervals=15;

deltat=(tmax-tmin)/numberIntervals

TableForm[  Table[  {t, N[ x[t] ], N[ y[t] ]}, {t, tmin, tmax, deltat}]  ]

Clear[points];
points=Table[Graphics[{PointSize[0.02`],Point[{x[t],y[t]}]}],{t,tmin,tmax,deltat}];
Show[{plotAll,points},PlotRange->{{xmin,xmax},{ymin,ymax}},Axes->True,AspectRatio->Automatic,AxesLabel->{"    x[t]","y[t]"}]

Why are the points so bunched near the origin?  Do the following plots help explain this?  What kind of Cal I analysis is helpful?  Do you get the idea of speed and velocity?

Plot[x[t],{t,tmin,tmax},PlotStyle->{colorx},AxesLabel->{"    t","x[t]"}]

Plot[y[t],{t,tmin,tmax},PlotStyle->{colory},AxesLabel->{"    t","y[t]"}]

Try to choose t-values so that points are fairly evenly distributed on a portion of the graph.  What is the implication of having different t-increments to get roughly the same arclength?

Clear[tlist2,points2];
tlist2={0,0.1`,0.2`,0.3`,0.5`,0.7`,0.9`,1.1`,1.3`,1.7`,3,10};
points2=Table[Graphics[{PointSize[0.02`],Point[{x[t],y[t]}]}]/.t->tlist2[[i]],{i,1,Length[tlist2]}];
Show[{plotAll,points2},PlotRange->{{xmin,xmax},{ymin,ymax}},Axes->True,AspectRatio->Automatic,AxesLabel->{" x[t] "," y[t] "}]

Speed

Animation shows speed

Clear[numberIntervals, deltat];

numberIntervals=60.0;

deltat=(tmax-tmin)/numberIntervals

Clear[dotsize];
dotsize = Max[{ymax-ymin,xmax-xmin}]/100.;

Manipulate[Show[
plotAll,
Graphics[{
{colorx,PointSize[.02],Point[{x[t],0}]},
{colory,PointSize[.02],Point[{0,y[t]}]},
{colorr,Circle[{x[t ],y[t ]},dotsize]},
{colorr,Circle[{x[t],y[t]},dotsize*2]},
{colorr,Circle[{x[t],y[t]},dotsize*3]}
                 }],
PlotRange-> {{xmin,xmax},{ymin,ymax}},Axes->Automatic,AspectRatio->Automatic,
AxesLabel->{"    x[t]","y[t]"}],{t,tmin,tmax,deltat}]

The equidistant t-values are used to illustrate speed.

Speed function

Use the speed function and Cal I concepts to explain.

Clear[speed];
speed[t_]:=(Sqrt[((x'[t])^2)+((y'[t])^2)])
Plot[speed[t],{t,tmin,tmax},PlotRange->{0,1.5}]