Velocity

Dr. Therese Shelton
Southwestern University
Georgetown, TX

It is expected that the reader has already seen the files parm1, parm2, parm3 first.

Basics

Clearing out the variables used avoids problems.

Clear[x,y,tmin,tmax, xmin,xmax,ymin,ymax,plotAll]

Define the functions for the parametric plot.

x[t_]:=(((t^3) - t)/((t^4) + 1));
 y[t_]:=(( t)/((t^4) + 1));

Define the graphing window.

tmin=-10;     tmax=10;
xmin = -0.5; xmax=0.5;
ymin=-0.6;   ymax=0.6;

A static image

plotAll=ParametricPlot[{x[t],y[t]},{t,tmin,tmax},PlotRange->{{xmin,xmax},{ymin,ymax}},AspectRatio->Automatic]

Static Velocity vectors

Be sure to load the Arrow package first.  No need to load it more than once.  (The <<Graphics`Arrow` cell is an initialization cell in this notebook, so it should have already executed.)

Expand the graphing window to show all the arrowheads.

Question for students:
In a short essay, discuss the implication of the length and direction of the velocity vectors.  In particular, relate position and velocity in motion terms.

Clear[arrowlist,plotPart,tlist2];
tlist2={0,0.1`,0.2`,0.3`,0.5`,0.7`,0.9`,1.1`,1.3`,1.7`,3,10};
plotPart=ParametricPlot[{x[t],y[t]},{t,0,tmax},PlotRange->{{xmin,xmax},{ymin,ymax}},AspectRatio->Automatic]
arrowlist=Table[Graphics[Arrow[{x[t],y[t]},{x[t]+x'[t],y[t]+y'[t]}]]/.t->tlist2[[i]],{i,1,Length[tlist2],2}];
Show[{plotPart,arrowlist},PlotRange->{{xmin,xmax},{ymin,ymax}},Axes->True,AspectRatio->Automatic,AxesLabel->{"    x[t]","y[t]"}]

Show[{plotPart,arrowlist},PlotRange->{{-2,2},{-0.5`,2}},Axes->True,AspectRatio->Automatic,AxesLabel->{"    x[t]","y[t]"}]

Relate numerical and graphical values.
For instance, 
	"at t=0, the parametric function passes through the origin with a velocity of {-1,1} and speed 1.41421.  Thus, from the origin, the function moves up and to the left fairly quickly, compared to speeds for t>1.5", etc.

Note that the velocity vector is tangent to the parametric function.

TableForm[
Table[
{t, N[{x[t],y[t]}],N[{x'[t],y'[t]}],N[(Sqrt[(((x'[t]))^2)+(((y'[t]))^2)])]}
/.t->tlist2[[i]],
{i,1,Length[tlist2],2}]]

Animated vectors

Clear[numberIntervals, deltat];

numberIntervals=60.0;

deltat=(tmax-tmin)/numberIntervals

Here are some of the values used.

TableForm[
Table[
{t, N[{x[t],y[t]}],N[{x'[t],y'[t]}],N[(Sqrt[(((x'[t]))^2)+(((y'[t]))^2)])]},
{t,tmin,tmax,deltat*5}]     ]

Clear[colorr,colorv]

colorr=RGBColor[1.,0.,0.]; 
colorv=RGBColor[0.,0.,1.];

colr="red";
colv="blue";

StringJoin["The r vector is ",colr,", and the velocity vector is ",colv]

A relative scaling of the window can help show the heads of all the vectors.

Manipulate[Show[
plotAll,
Graphics[{colorr,Arrow[ {0,0}, {x[t], y[t]} ]} ],
Graphics[{colorv,Arrow[ {x[t],y[t]}, {x[t] + x'[t], y[t] + y'[t]} ] }],
PlotRange-> {{xmin-(xmax-xmin)/2,xmax+(xmax-xmin)/2},{ymin-(ymax-ymin)/2,ymax+(ymax-ymin)/2}},Axes->Automatic,AspectRatio->Automatic,
AxesLabel->{"    x[t]","y[t]"}],{t,tmin,tmax,deltat}]

The velocity vector (at least for this curve) looks like it's pulling or pushing the position vector.

Questions for students:
1)What direction does the acceleration vector point, relative to the parametric function?
2)When are the acceleration and velocity vectors at a single point perpendicular for all points of the parametric function?  Are they for this function?
(Hint:  what operation can be performed on two vectors to determine whether they are orthogonal?  What vector is orthogonal to any vector?)